Доброго дня!!! Заголовок корявый, не смог лучше описать проблему. Итак, у нас есть договоры, в которых есть реквизит Объект строительства и есть реквизит Статья ДДС. По одному объекту строительства м.б. несколько договоров с разными статьями ДДС. Задача  узнать статью ДДС в разрезе объектов строительства, по который был максимальный оборот за период. Мой запрос был такой:
|ВЫБРАТЬ РАЗРЕШЕННЫЕ РАЗЛИЧНЫЕ
|    Договоры.ОбъектСтроительства КАК ОбъектСтроительства,
|    ХозрасчетныйОбороты.Субконто1.ОсновнаяСтатьяДвиженияДенежныхСредств КАК СтатьяДДС,
|    МАКСИМУМ(ХозрасчетныйОбороты.СуммаОборот) КАК Сумма
|ПОМЕСТИТЬ Финанс
|ИЗ
|    Договоры КАК Договоры
|    ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Хозрасчетный.Обороты(&ДатаНачала, &ДатаКонца, , , &ВидСубконто1, , КорСчет = &Сч51, ) КАК ХозрасчетныйОбороты
ПО Договоры.Договор = ХозрасчетныйОбороты.Субконто1
|
|СГРУППИРОВАТЬ ПО
|    Договоры.ОбъектСтроительства,
|ХозрасчетныйОбороты.Субконто1.ОсновнаяСтатьяДвиженияДенежныхСредств

Но там несколько статей ДДС. А нужно одну.

Убери строчку   Договоры.ОбъектСтроительства КАК ОбъектСтроительства,

(0) Тебе данный отбор нужно поместить во временную таблицу, а затем группировать по объекту и найти максимальную сумму. Затем соединить результат по объекту и сумме со временной, что бы найти ту самую максимальную ДДС

аналогичная задача, для каждого контрагента вывести договор с максимальным оборотом продаж:


ВЫБРАТЬ
    ПродажиОбороты.Контрагент,
    ПродажиОбороты.ДоговорКонтрагента,
    ПродажиОбороты.СтоимостьОборот
ПОМЕСТИТЬ ТЗ
ИЗ
    РегистрНакопления.Продажи.Обороты КАК ПродажиОбороты
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ТЗ.Контрагент,
    МАКСИМУМ(ТЗ.СтоимостьОборот) КАК СтоимостьОборот
ПОМЕСТИТЬ Максимумы
ИЗ
    ТЗ КАК ТЗ

СГРУППИРОВАТЬ ПО
    ТЗ.Контрагент
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ТЗ.Контрагент КАК Контрагент,
    ТЗ.ДоговорКонтрагента,
    ТЗ.СтоимостьОборот
ИЗ
    ТЗ КАК ТЗ
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ Максимумы КАК Максимумы
        ПО ТЗ.Контрагент = Максимумы.Контрагент
            И ТЗ.СтоимостьОборот = Максимумы.СтоимостьОборот

УПОРЯДОЧИТЬ ПО
    Контрагент
АВТОУПОРЯДОЧИВАНИЕ

Всем ааагромное спасибо!!! Все получилось!