Здравствуйте! Столкнулся со следующей проблемой - не могу заполнить вложенные свойства в объекте XDTO. Тип в пакете выглядит приблизительно следующим образом:

ОбъектXDTO: insurer_id_t
    СвойствоXDTO: InsurerId
        ОбъектXDTO: Определение типа
            СвойствоXDTO: CmbndId
                 ОбъектXDTO: Определение типа
                     СвойствоXDTO: ClrSysMmbId
                         ОбъектXDTO: Определение типа
                              СвойствоXDTO: Id

В XML это выглядит так:

<xs:complexType name="insurer_id_t">
        <xs:all>
            <xs:element name="InsurerId">
                <xs:complexType>
                    <xs:all>
                        <xs:element name="CmbndId">
                            <xs:complexType>
                                <xs:all>
                                    <xs:element name="ClrSysMmbId">
                                        <xs:complexType>
                                            <xs:all>
                                                <xs:element name="Id" type="tns:idd_t"/>
                                            </xs:all>
                                        </xs:complexType>
                                    </xs:element>
                                </xs:all>
                            </xs:complexType>
                        </xs:element>
                    </xs:all>
                </xs:complexType>
            </xs:element>
        </xs:all>
    </xs:complexType>

Вот заполнить мне нужно именно тег ID, не могу понять как к нему подобраться.

ну ... код-то где?

Да какой там код-то...
ЛокальноеПространствоИмен = "ЛокальноеПространствоИмен";
ТипXDTO = ФабрикаXDTO.Тип(ЛокальноеПространствоИмен, "insurer_id_t");
    ОбъектXDTO = ФабрикаXDTO.Создать(ТипXDTO);

Собственно и весь код. К свойству ОбъектXDTO.InsurerId еще есть доступ, а вот как добраться до Определений типа и их свойствам - не пойму.

1С не может в объявления типов по месту использования; пару лет назад вроде писал уже об этом на партнерке, но воз и ныне там.

(3) может

(4) нужно получить свойство объекта, у него тип, и по типу создать новый обхект


ТипСтрокиТЧ = Документ.Тип().Свойства.Получить("ТЧ").Тип;
пСтрокаТЧ = ФабрикаXDTO.Создать(ТипСтрокиТЧ);


Спасибо, действительно помогло. Правда я не совсем понял, что за код Вы написали. Применительно к описанной проблеме, у меня получилось так, в продолжение к предыдущему коду:


    СвойствоInsurerId =   ОбъектXDTO.Свойства().Получить("InsurerId");
    InsurerId = ФабрикаXDTO.Создать(СвойствоInsurerId.Тип);
    СвойствоCmbndId = InsurerId.Свойства().Получить("CmbndId");
    CmbndId = ФабрикаXDTO.Создать(СвойствоCmbndId.Тип);
    СвойствоClrSysMmbId = CmbndId.Свойства().Получить("ClrSysMmbId");
    ClrSysMmbId = ФабрикаXDTO.Создать(СвойствоClrSysMmbId.Тип);
    ClrSysMmbId.Id = "ТребуемоеЗначение";
    CmbndId.ClrSysMmbId = ClrSysMmbId;
    InsurerId.CmbndId = CmbndId;
    ОбъектXDTO.InsurerId = InsurerId;

(4) не всегда

(8) ну и рекурсией в дерево

// Возвращает структуру со всеми типами:
// каждое имя структуры содержит обязательное поле Тип
// и необязательное поле с подчинённой структурой следующего типа
// например: package.Тип - тип корневого элемента
// package.body - подчинённый элемент
// package.body.Тип - тип элемента body
// package.body.bill - подчинённый элемент
// package.body.bill.Тип - тип элемента bill
Функция     ПолучитьСтруктуруТиповXDTOПакета(ТекущийЭлемент)
    ТипЭлемента = Новый Структура("Тип", ТекущийЭлемент);
    Для каждого Свойство из ТекущийЭлемент.Свойства Цикл
        Если Свойство.Форма = ФормаXML.Элемент Тогда
            ТипЭлемента.Вставить(Свойство.Имя, ПолучитьСтруктуруТиповXDTOПакета(Свойство.Тип));
        КонецЕсли;
    КонецЦикла;
    Возврат ТипЭлемента;
КонецФункции